/****/
/* PROGRAM:  Example SAS Analysis Programs.SAS                     	      */
/*                                                                        */
/* PURPOSE:  THIS PROGRAM PROVIDES EXAMPLE ANALYSIS CODE FOR PRODUCING 	  */
/*			 ESTIMATES FROM THE 2023 NIS-TEEN PUF USING SAS.	          */
/*			 THE PROGRAM IS DIVIDED INTO FIVE SECTIONS:        		      */
/*                                                                        */
/* EXAMPLE 1:   PRODUCE ESTIMATION AREA ESTIMATES AND STANDARD ERRORS     */
/*				FOR 1+ TD/TDAP VACCINATIONS (P_UTDTD)                     */
/*                                                                        */
/* EXAMPLE 2:   PRODUCE STATE ESTIMATES AND STANDARD ERRORS 			  */
/*              FOR 1+ TD/TDAP VACCINATIONS (P_UTDTD)                     */
/*                                                                        */
/* EXAMPLE 3:   PRODUCE A TABLE OF HOUSEHOLD REPORT OF  				  */
/*              THE TEEN HAVING ASTHMA BY STATE FOR ALL HOUSEHOLD  		  */
/*				COMPLETES USING RDDWT_C                                   */
/*                                                                        */
/* EXAMPLE 4:   PRODUCE A TABLE OF P_UTDTD BY INCPOV1 BY RACE_K           */
/*                                                                        */
/* EXAMPLE 5:   PRODUCE A BAR CHART OF P_UTDTD BY INCPOV1 BY RACE_K       */
/****/

options ps = 78 ls = 90 obs = max;

*--- ASSIGN SAS LIBRARIES AND FILE NAMES ---*;  
libname dd 'c:\nisteenpuf23'; *--- Specify path to sas dataset ---*;
libname library 'c:\nisteenpuf23'; *--- If dataset was created with formats stored ---*;
%let out = 'c:\nisteenpuf23'; *--- Specify output location ---*; 
libname out &out.;

*--- PERMANENTLY SPECIFY PATH TO LIBRARY ---*;
*--- OTHERWISE COMMENT THIS STATEMENT OUT ---*;
%let yy = 23; *--- YEAR OF DATA COLLECTION ---*;
%let in_file = dd.nisteenpuf&yy.; *--- NAME OF SAS DATASET ---*;
%let ESTIAP = ESTIAPt&yy.; * --- ESTIMATION AREA VARIABLE TO USE ---*;
%let RDDWT = RDDWT_C; * --- Weight to use for household variables (RDDWT_C is the single-frame cellular phone weight excluding territories. Use RDDWT_C_TERR to include territories) ---*;
%let PROVWT = PROVWT_C; * --- Weight to use for provider variables (PROVWT_C is the single-frame cellular phone weight excluding territories. Use PROVWT_C_TERR to include territories) ---*;
%let STRAT = STRATUM; * --- STRATUM variable to use for variance estimation (use STRATUM for all estimation) ---*;


*--- DEFINE FORMATS USED FOR ANALYSIS ---*;
proc format;

	value p_utdtdf
		0 = 'Not 1+ Td/Tdap Up-To-Date'
		1 = '1+ Td/Tdap Up-To-Date'
		;
	
	value ESTIAPf
		. = "Missing"
		0 = "U.S. Total"
		1 = "CT"
		2 = "MA"
		4 = "ME"
		5 = "NH"
		6 = "RI"
		7 = "VT"
		8 = "NJ"
		10 = "NY-Rest of State"
		11 = "NY-City of New York"
		12 = "DC"
		13 = "DE"
		14 = "MD"
		16 = "PA-Rest of State"
		17 = "PA-Philadelphia County"
		18 = "VA"
		19 = "WV"
		20 = "AL"
		22 = "FL"
		25 = "GA"
		27 = "KY"
		28 = "MS"
		29 = "NC"
		30 = "SC"
		31 = "TN"
		34 = "IL-Rest of State"
		35 = "IL-City of Chicago"
		36 = "IN"
		38 = "MI"
		40 = "MN"
		41 = "OH"
		44 = "WI"
		46 = "AR"
		47 = "LA"
		49 = "NM"
		50 = "OK"
		51 = "TX-Rest of State"
		54 = "TX-City of Houston"
		55 = "TX-Bexar County"
		56 = "IA"
		57 = "KS"
		58 = "MO"
		59 = "NE"
		60 = "CO"
		61 = "MT"
		62 = "ND"
		63 = "SD"
		64 = "UT"
		65 = "WY"
		66 = "AZ"
		68 = "CA"
		72 = "HI"
		73 = "NV"
		74 = "AK"
		75 = "ID"
		76 = "OR"
		77 = "WA"
		106 = "Puerto Rico"
		;
		
	value statef
		0 = "U.S. Total"
		1 = "Alabama"
		2 = "Alaska"
		4 = "Arizona"
		5 = "Arkansas"
		6 = "California"
		8 = "Colorado"
		9 = "Connecticut"
		10 = "Delaware"
		11 = "District of Columbia"
		12 = "Florida"
		13 = "Georgia"
		15 = "Hawaii"
		16 = "Idaho"
		17 = "Illinois"
		18 = "Indiana"
		19 = "Iowa"
		20 = "Kansas"
		21 = "Kentucky"
		22 = "Louisiana"
		23 = "Maine"
		24 = "Maryland"
		25 = "Massachusetts"
		26 = "Michigan"
		27 = "Minnesota"
		28 = "Mississippi"
		29 = "Missouri"
		30 = "Montana"
		31 = "Nebraska"
		32 = "Nevada"
		33 = "New Hampshire"
		34 = "New Jersey"
		35 = "New Mexico"
		36 = "New York"
		37 = "North Carolina"
		38 = "North Dakota"
		39 = "Ohio"
		40 = "Oklahoma"
		41 = "Oregon"
		42 = "Pennsylvania"
		44 = "Rhode Island"
		45 = "South Carolina"
		46 = "South Dakota"
		47 = "Tennessee"
		48 = "Texas"
		49 = "Utah"
		50 = "Vermont"
		51 = "Virginia"
		53 = "Washington"
		54 = "West Virginia"
		55 = "Wisconsin"
		56 = "Wyoming"
		72 = "Puerto Rico"
		;

	value asthmaf
		1 = 'Yes'
		2 = 'No'
		;
	
	value incpvr2f
		1 = "Above Poverty, > $75,000"
		2 = "Above Poverty, < = $75,000"
		3 = "Below Poverty"
		4 = "Unknown"
		;
		
	value race_kf
		1 = "White Only"
		2 = "Black Only"
		3 = "Other/Mult Race"
		;
run;

data nisteenpuf;
	set &in_file. (keep = SEQNUMT &ESTIAP. &RDDWT. &PROVWT. &STRAT. STATE PDAT2 P_UTDTD P_UTDMMR ASTHMA RACE_K INCPOV1);
	format &ESTIAP. ESTIAPf. 
		   STATE statef.
		   P_UTDTD p_utdtdf.	   
		   ASTHMA asthmaf.
		   INCPOV1 incpvr2f.
		   RACE_K race_kf.;
run;






EXAMPLE 1:	PRODUCE ESTIMATION AREA ESTIMATES AND STANDARD
			ERRORS FOR 1+ TD/TDAP VACCINATIONS (P_UTDTD)
;

proc sort data = nisteenpuf;by &ESTIAP.;run;

ods exclude all;
ods output statistics = sas_est;
proc surveymeans data = nisteenpuf nobs sum mean stderr;
	stratum &STRAT.;
	cluster SEQNUMT;
	weight &PROVWT.;
	class P_UTDTD;
	var P_UTDTD;
	by &ESTIAP.;
run;
ods exclude none;

data sas_est;
	set sas_est;
	mean = mean*100; *Convert to percent estimates;
	stderr = stderr*100;
run;

proc print data = sas_est (where = (varlevel = '1+ Td/Tdap Up-To-Date')) noobs label;
	format mean stderr 5.2;
	var &ESTIAP. mean stderr;
	label mean = 'Percent 1+ Td/Tdap Up-to-Date'
		  stderr = 'Standard Error';
	title1 '1+ Td/Tdap Estimates by Estimation Area';
run;




***
EXAMPLE 2:	PRODUCE STATE ESTIMATES AND STANDARD ERRORS				
			FOR 1+ TD/TDAP VACCINATIONS (P_UTDTD)					
***;

proc sort data = nisteenpuf;by STATE;run;

ods exclude all;
ods output statistics = sas_est2;
proc surveymeans data = nisteenpuf nobs sum mean stderr;
	stratum &STRAT.;
	cluster SEQNUMT;
	weight &PROVWT.;
	class P_UTDTD;
	var P_UTDTD;
	by STATE;
run;
ods exclude none;

data sas_est2;
	set sas_est2;
	mean = mean*100; *Convert to percent estimates;
	stderr = stderr*100;
run;

proc print data = sas_est2 (where = (varlevel = '1+ Td/Tdap Up-To-Date')) noobs label;
	format mean stderr 5.2;
	var STATE mean stderr;
	label mean = 'Percent 1+ Td/Tdap Up-to-Date'
		  stderr = 'Standard Error';
	title '1+ TD/Tdap Estimates by State';
run;




***
EXAMPLE 3:	PRODUCE A TABLE OF HOUSEHOLD REPORT OF 
			THE TEEN HAVING ASTHMA BY STATE FOR ALL HOUSEHOLD COMPLETES USING RDDWT_C
***;

ods exclude all;
ods output Statistics = sas_est3;

proc sort data = nisteenpuf;by STATE;run;
proc surveymeans data = nisteenpuf nobs sum mean stderr;
	stratum &STRAT.;
	cluster SEQNUMT;
	weight &RDDWT.;
	class ASTHMA;
	var ASTHMA;
	by STATE;
run;
ods exclude none;

data sas_est3;
	set sas_est3;
	mean = mean*100; *Convert to percent estimates;
	stderr = stderr*100;
run;

proc print data = sas_est3 (where = (varlevel = 'Yes')) noobs label;
	format STATE statef. mean stderr 5.2;
	var STATE mean stderr;
	label mean = 'Percent ASTHMA = Yes'
		  stderr = 'Standard Error';
	title 'HH-Reported Asthma Estimates by State';
run;




***
EXAMPLE 4:	PRODUCE A TABLE OF P_UTDTD BY INCPOV1 BY RACE_K
***;

proc sort data = nisteenpuf;by incpov1 race_k;run;
proc freq data = nisteenpuf;
	where PDAT2 = 1;
	tables P_UTDTD INCPOV1 RACE_K;
	title1 "Table 4A. Q1/20&yy. - Q4/20&yy.: Unweighted Frequencies";
run;

ods exclude all;
proc surveymeans data = nisteenpuf nobs sum mean stderr;
	ods output Domain = sas_est4;
	stratum &STRAT.;
	cluster SEQNUMT;
	weight &PROVWT.;
	class P_UTDTD;
	var P_UTDTD;
	domain INCPOV1*RACE_K;
run;
ods exclude none;

data sas_est4;
	set sas_est4;
	mean = mean*100; *Convert to percent estimates;
	stderr = stderr*100;
run;

proc print data = sas_est4 (where = (varlevel = '1+ Td/Tdap Up-To-Date')) noobs label;
	var INCPOV1 RACE_K mean stderr;
	label mean = '1+ Td/Tdap Up-To-Date'
		  stderr = 'Standard Error';
	title "Table 4B. Q1/20&yy. - Q4/20&yy.: 1+ TD/Tdap Estimates by INCPOV1 by RACE_K";
run;

data out.sas_est4;
	set sas_est4 (where = (varlevel = '1+ Td/Tdap Up-To-Date'));
	keep INCPOV1 RACE_K mean;
	label mean = '1+ Td/Tdap Up-to-Date';
	format rowper serow 5.2 RACE_K race_kf. INCPOV1 incpvr2f.;
run;




***
EXAMPLE 5:	PRODUCE A BAR CHART OF P_UTDTD BY INCPOV1 BY RACE_K
***;

data sas_est4;
	set out.sas_est4;
	format mean 3.   
		   INCPOV1 incpvr2f.
		   RACE_K race_kf.;
	label RACE_K = 'Race of Teen'
		  INCPOV1 = 'Poverty Status';
	filename odsout &out.;
	ods listing close;
	
	*Set the graphics environment;
	goptions reset = global gunit = pct border ftext = swissb htitle = 4 htext = 1.5 device = gif;
	ods html body = 'graph_4.html' path = odsout;
run;

title1 h = 12pt "Percentage of Teens Up-to-Date with 1+ Td/Tdap";
title2 h = 12pt "by Race and Poverty Status, National Immunization Survey - Teen, 20&yy.";
footnote j = r 'graph_4';

proc sgplot data = sas_est4;
	styleattrs datacolors = (wheat lightpink forestgreen) datacontrastcolors = (wheat lightpink forestgreen) datalinepatterns = (solid);
	vbar INCPOV1 / response = mean group = RACE_K groupdisplay = cluster stat = mean barwidth = 0.8;
	xaxis display = (noticks);
	yaxis grid;
	keylegend / across = 1 position = top;
run;

ods html close;
ods listing;